MAPLE output for calculating Pi using the Taylor Series for 6*arcsin(x) at x=1/2.

We know that the arcsin(1/2) = Pi/6.

> 6*arcsin(1/2); evalf(%);

Pi

3.141592654

So, we can get Pi by finding 6 times the Taylor Series for arcsin(x), evaluating the series at x=1/2.

How can we find the Taylor Series for arcsin(x)?

Well, the derivative of the arcsin(x) is:

> f:=diff(arcsin(x),x);

f := 1/(sqrt(1-x^2))

So, if we find the Taylor Series for f(x), we can integrate it to get the Taylor Series for arcsin(x).

Let's find out a few derivatives for f(x) and plug in a=0.

> fp:=diff(f,x); subs(x=0, fp);

fp := x/((1-x^2)^(3/2))

0

> fpp:=diff(fp,x); subs(x=0, fpp);

fpp := 3*x^2/((1-x^2)^(5/2))+1/((1-x^2)^(3/2))

1

> fppp:=diff(fpp,x); subs(x=0, fppp);

fppp := 15*x^3/((1-x^2)^(7/2))+9*x/((1-x^2)^(5/2))

0

> fpppp:=diff(fppp,x); subs(x=0, fpppp);

fpppp := 105*x^4/((1-x^2)^(9/2))+90*x^2/((1-x^2)^(7...

9

> fppppp:=diff(fpppp,x); subs(x=0, fppppp);

fppppp := 945*x^5/((1-x^2)^(11/2))+1050*x^3/((1-x^2...

0

> fpppppp:=diff(fppppp,x); subs(x=0, fpppppp);

fpppppp := 10395*x^6/((1-x^2)^(13/2))+14175*x^4/((1...

225

So, the beginning of the Taylor Series for 1/sqrt(1-x^2) is:

> taylor(1/sqrt(1-x^2), x=0, 7);

series(1+1/2*x^2+3/8*x^4+5/16*x^6+O(x^8),x,8)

We can integrate this to get the Taylor Series for arcsin(x):

> taylor(arcsin(x), x=0, 8);

series(1*x+1/6*x^3+3/40*x^5+5/112*x^7+O(x^8),x,8)

Now that we have the Taylor Series for the arcsin(x), we can find 6 times it, and evaluate it at x=1/2 in order to get Pi.

The 7th order Taylor Series for 6*arcsin(x), and its value at x=1/2 are:

> mtaylor(6*arcsin(x), x=0, 8); evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 8)));

6*x+x^3+9/20*x^5+15/56*x^7

3.141155134

The 9th order Taylor Series for 6*arcsin(x), and its value at x=1/2 are:

> mtaylor(6*arcsin(x), x=0, 10); evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 10)));

6*x+x^3+9/20*x^5+15/56*x^7+35/192*x^9

3.141511172

The 11th order Taylor Series for 6*arcsin(x), and its value at x=1/2 are:

> mtaylor(6*arcsin(x), x=0, 12); evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 12)));

6*x+x^3+9/20*x^5+15/56*x^7+35/192*x^9+189/1408*x^11...

3.141576716

Here are some higher order evaluations:

> evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 20)));

3.141592623

> evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 24)));

3.141592652

Finally, using (only) a 25th order Taylor Series, we get Pi correct to eight places.

> evalf(subs(x=1/2, mtaylor(6*arcsin(x), x=0, 26))); evalf(Pi-%);

3.141592653

.1e-8